all.bat

@echo off
cd /d %~dp0
chcp 65001 >nul
setlocal

rem Ves progon odnoy komandoy. Zapuskat s nomerom mashiny: all.bat Comp_1

set NAME=%~1
if "%NAME%"=="" set NAME=%COMPUTERNAME%
set OUT=Results\%NAME%
if not exist "%OUT%" mkdir "%OUT%"

echo ==========================================================
echo  ChunkProof
echo  Mashina: %NAME%
echo  Rezultaty: %OUT%
echo ==========================================================
echo.

where dotnet >nul 2>&1
if errorlevel 1 goto nodotnet

echo [1/9] Proverka SDK .NET 8, 9 i 10
for %%V in (8 9 10) do (
  dotnet --list-sdks | findstr /b "%%V." >nul
  if errorlevel 1 goto nosdk
)
echo       ok
echo.

echo [2/9] Build i chistka proshlogo progona
rmdir /s /q BenchmarkDotNet.Artifacts 2>nul
dotnet build -c Release > "%OUT%\build.txt" 2>&1
if errorlevel 1 goto buildfail
echo       ok
echo.

echo [3/9] Sverka otvetov na treh runtaymah
for %%R in (net8.0 net9.0 net10.0) do (
  dotnet run -c Release -f %%R --no-build -- checks > "%OUT%\checks-%%R.txt" 2>&1
  if errorlevel 1 goto checksfail
)
echo       ok
echo.

echo [4/9] Otchety blocks i threshold na treh runtaymah
for %%R in (net8.0 net9.0 net10.0) do (
  dotnet run -c Release -f %%R --no-build -- blocks    > "%OUT%\blocks-%%R.txt"    2>&1
  dotnet run -c Release -f %%R --no-build -- threshold > "%OUT%\threshold-%%R.txt" 2>&1
)
echo       ok
echo.

echo [5/9] Pamyat. Kazhdyy sposob svoim processom, chetyre razmera chanka
for %%R in (net8.0 net9.0 net10.0) do (
  for %%S in (1000 10000 20000 25000) do (
    call :mem %%R %%S chunkArray
    call :mem %%R %%S chunkList
    call :mem %%R %%S chunkEnumerable
    call :mem %%R %%S chunkStrings
    call :mem %%R %%S chunkHeld
    call :mem %%R %%S slicesHeld
    call :mem %%R %%S chunkStringsHeld
    call :mem %%R %%S stringSlicesHeld
    call :mem %%R %%S spanSlices
    call :mem %%R %%S spanFromList
    call :mem %%R %%S reusedBuffer
    call :mem %%R %%S pooledBuffer
  )
)
echo       ok
echo.

echo [6/9] Sborki po pokoleniyam. Kazhdyy vid svoim processom
for %%R in (net8.0 net9.0 net10.0) do (
  call :col %%R 21243 chunkArray
  call :col %%R 21244 chunkArray
  call :col %%R 25000 chunkArray
  call :col %%R 10000 chunkStrings
  call :col %%R 10622 chunkStrings
  call :col %%R 21244 spanSlices
)
echo       ok
echo.

echo [7/9] Servernyy sborshchik
set DOTNET_gcServer=1
call :mem net10.0 20000 chunkArray-srv chunkArray
call :mem net10.0 20000 chunkStrings-srv chunkStrings
call :mem net10.0 25000 chunkHeld-srv chunkHeld
call :mem net10.0 20000 chunkStringsHeld-srv chunkStringsHeld
call :col net10.0 21243 chunkArray-srv chunkArray
call :col net10.0 21244 chunkArray-srv chunkArray
set DOTNET_gcServer=
echo       ok
echo.

echo [8/9] Podnyatyy porog LOH. Prichinnaya proverka: te zhe chanki vne LOH
echo       Okolo soroka minut: 30 zamerov na treh runtaymah
rem Esli zamedlenie na 21244 vyzvano imenno kuchey bolshih obektov, to
rem pri poroge 0x30000 (196 608 bayt) tot zhe blok tuda ne popadaet,
rem i raznica obyazana ischeznut. Esli ne ischezla - delo ne v LOH.
set DOTNET_GCLOHThreshold=0x30000
dotnet run -c Release -f net10.0 --no-build -- threshold > "%OUT%\threshold-loh192k.txt" 2>&1
dotnet run -c Release -f net10.0 --no-build -- blocks    > "%OUT%\blocks-loh192k.txt"    2>&1
call :mem net10.0 25000 chunkHeld-loh192k chunkHeld
call :mem net10.0 20000 chunkStringsHeld-loh192k chunkStringsHeld
call :col net10.0 21243 chunkArray-loh192k chunkArray
call :col net10.0 21244 chunkArray-loh192k chunkArray
call :col net10.0 25000 chunkArray-loh192k chunkArray
call :col net10.0 10622 chunkStrings-loh192k chunkStrings
rmdir /s /q BenchmarkDotNet.Artifacts 2>nul
dotnet run -c Release -f net10.0 --no-build -- --filter *ChunkValueBench* *ChunkHeldBench*
if errorlevel 1 goto causefail
if exist BenchmarkDotNet.Artifacts\results (
  if not exist "%OUT%\bench-loh192k" mkdir "%OUT%\bench-loh192k"
  xcopy /y /q BenchmarkDotNet.Artifacts\results\*.* "%OUT%\bench-loh192k\" > nul
)
set DOTNET_GCLOHThreshold=
echo       ok
echo.

echo [9/9] Zamery. Okolo dvuh s polovinoy chasov, 7 klassov, 166 zamerov
rmdir /s /q BenchmarkDotNet.Artifacts 2>nul
dotnet run -c Release -f net10.0 --no-build
if errorlevel 1 goto benchfail
if exist BenchmarkDotNet.Artifacts\results (
  if not exist "%OUT%\bench" mkdir "%OUT%\bench"
  xcopy /y /q BenchmarkDotNet.Artifacts\results\*.* "%OUT%\bench\" > nul
  copy /y BenchmarkDotNet.Artifacts\*.log "%OUT%\bench\" > nul 2>&1
)
dotnet --info > "%OUT%\environment.txt" 2>&1
powershell -NoProfile -Command "Get-CimInstance Win32_Processor | Select-Object Name, NumberOfCores, NumberOfLogicalProcessors | Format-List" >> "%OUT%\environment.txt" 2>&1
powershell -NoProfile -Command "'RAM bytes: ' + (Get-CimInstance Win32_ComputerSystem).TotalPhysicalMemory" >> "%OUT%\environment.txt" 2>&1
echo       ok
echo.

echo Gotovo. Vsyo lezhit v %OUT%
pause
exit /b 0

:mem
rem %1 - runtime, %2 - razmer chanka, %3 - imya fayla, %4 - vid.
rem Esli %4 pust, imya fayla i vid sovpadayut.
set KIND=%4
if "%KIND%"=="" set KIND=%3
dotnet run -c Release -f %1 --no-build -- memory %KIND% %2 > "%OUT%\memory-%1-%2-%3.txt" 2>&1
exit /b 0

:col
rem %1 - runtime, %2 - razmer chanka, %3 - imya fayla, %4 - vid.
set KIND=%4
if "%KIND%"=="" set KIND=%3
dotnet run -c Release -f %1 --no-build -- collect %KIND% %2 > "%OUT%\collect-%1-%2-%3.txt" 2>&1
exit /b 0

:nodotnet
echo DOTNET NE NAYDEN. Ustanovit SDK .NET 8, 9 i 10.
pause
exit /b 1

:nosdk
echo NE HVATAET SDK. Nuzhny .NET 8, 9 i 10. Proverit: dotnet --list-sdks
pause
exit /b 1

:buildfail
echo BUILD NE PROSHEL. Smotret %OUT%\build.txt
pause
exit /b 1

:checksfail
echo SVERKA OTVETOV NE PROSHLA. Smotret %OUT%\checks-*.txt
pause
exit /b 1

:causefail
echo PRICHINNAYA PROVERKA NE PROSHLA. Bez neyo vyvod pro LOH nedokazan.
pause
exit /b 1

:benchfail
echo ZAMERY NE PROSHLI.
pause
exit /b 1