base-sdk/Justfile at develop · dashpay/base-sdk · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
set windows-shell := ["powershell.exe", "-NoLogo", "-Command"]

python := if os() == "windows" { "python" } else { "python3" }

# `[env]` attribute unavailable on just 1.40 packaged with Debian trixie
# (see https://packages.debian.org/trixie/just)
export RUSTDOCFLAGS := "-D warnings"
export RUSTFLAGS := "-D warnings"

nextest := "cargo nextest run --config-file maint/nextest.toml --profile=ci"

[private]
default:
    @just --list

bench:
    cargo bench --workspace --features full

build:
    cargo build --workspace --features full
    cargo build --workspace --no-default-features

comb:
    {{ python }} contrib/git_filter.py --fast-fail develop HEAD -- just test lint

lint:
    @just --fmt --check
    {{ python }} maint/lint_all.py --exclude lint_codeql
    {{ python }} maint/lint/lint_codeql.py check
    {{ python }} maint/lint/lint_codeql.py run --lang=rust --with-suite=rust-security-and-quality

sh:
    nix develop ./contrib/nix#dev

preview:
    {{ python }} docs/build_docs.py preview

test:
    cargo clippy --all-targets --no-default-features
    cargo clippy --all-targets --features full
    {{ nextest }} --fail-fast --workspace --features full
    cargo test --doc --workspace --features full
    cargo doc --workspace --no-deps --features full
    cargo bench --workspace --features full --no-run